Skip to content

Monitor Your Home Anywhere with ESP32 & “ThingSpeak “๐ŸŒ

Ever wanted to keep an eye on your home’s temperature and humidity while you’re away?

So, let’s build a custom, affordable IoT monitoring device using an ESP32 microcontroller and a DHT sensor that sends temperature and humidity ๐ŸŒก๏ธ data to ThingSpeak (a popular IoT analytics platform).

You’ll be able to view real-time graphs and receive alerts from anywhere with an internet connection!

Before We Begin:ย If youโ€™re completely new to the ESP32, I recommend checking out my previous blog post, anย Ultimate ESP32 Beginnerโ€™s Guide. Weโ€™ve covered the basics of setting up your development environment, installing board support, and uploading your first program.

1๏ธโƒฃ What Youโ€™ll Need?

๐Ÿงฐ Components Required

  • ESP32 Development Boardย (any variant: ESP32 DevKit, NodeMCU-32S, etc.)
  • DHT11 or DHT22 Temperature/Humidity Sensor
  • Breadboardย (optional but recommended)
  • Jumper Wiresย (male-to-female or male-to-male)
  • Micro-USB Cableย for programming and power
  • 10kฮฉ Resistorย (only if using DHT11 without built-in pull-up)

๐Ÿ”ง I highly recommend getting a complete ESP32ย starter kit.
It will save you time, money, and frustrationโ€”and help you learn IoT much faster.

๐Ÿ“ฆ Software & Accounts

  • Arduino IDEย or VS Code & PlatformIO
  • ESP32 Board Support Packageย 
  • ThingSpeak Accountย (free atย thingspeak.com)

Note: If you havenโ€™t set up your Arduino IDE with ESP32 support yet, please follow my previous ESP32 setup guide before proceeding.

2๏ธโƒฃ What is ThingSpeak ๐ŸŒ?

ThingSpeak is an IoT cloud platform that allows you to collect, store, analyze, and visualize data from hardware devices like ESP32, Arduino, and Raspberry Pi.

In simple words: ๐Ÿ‘‰ it is the bridge between your ESP32 and the internet.

With ThingSpeak, you can:

  • ๐Ÿ“ก Receive sensor data from anywhere in the world
  • ๐Ÿ“Š Display live data using automatic graphs
  • โ˜๏ธ Store historical temperature & humidity values
  • ๐Ÿ“ฑ Access your data from any browser or phone
  • ๐Ÿง  Use MATLAB tools for analysis & alerts

โœ… In this project, the ESP32 reads temperature and humidity from a DHT sensor, then sends the data to ThingSpeak, where you can monitor your home remotely in real time ๐ŸŒ

3๏ธโƒฃ Step-by-Step Guide:

โš™๏ธ Step 1: Create a ThingSpeak Account & Channel

  1. Go to ThingSpeak.com and sign up (It is FREE)
  2. Log in, then click Channels โ†’ New Channel
  3. Give your channel a name (e.g: “ESP32-Monitoring“)
  4. Enable:
    • Field 1: Temperature (ยฐC)
    • Field 2: Humidity (%)
  5. Save the channel

๐Ÿ”‘ Go to API Keys and copy your Write API Key โ€“ youโ€™ll need it later in the code.

๐Ÿ”Œ Step 2: Wiring the DHT Sensor to ESP32

DHT Sensor Pins:

  • VCCย โ†’ ESP32ย 3.3Vย orย 5V
  • GNDย โ†’ ESP32ย GND
  • DATAย โ†’ ESP32ย GPIOย 26 (can be any digital pin)

โš ๏ธ Important Note:
If you are using aย DHT sensor without an internal pull-up resistor, connect aย 10kฮฉ resistor between VCC and DATA. This ensures reliable communication between the sensor and the ESP32.

๐Ÿง  Step 3: Install Required Libraries

Open Arduino IDE โ†’ Library Manager and install:

  • DHT sensor library by Adafruit
  • Adafruit Unified Sensor

๐Ÿ’ป Step 4: ESP32 Code

Here’s the complete sketch with detailed explanations. Replace the placeholder values with your actual credentials:

  • WiFi name & password
  • ThingSpeak API key
#include <WiFi.h>
#include <HTTPClient.h>
#include <DHT.h>

// Replace with your network credentials
const char* ssid = "REPLACE_WITH_YOUR_SSID";
const char* password = "REPLACE_WITH_YOUR_PASSWORD";

// Replace with your ThingSpeak API Key
String serverName = "http://api.thingspeak.com/update?api_key=REPLACE_WITH_YOUR_API_KEY";

// Timer setup
unsigned long lastTime = 0;
const unsigned long timerDelay = 5000; // 5 seconds delay

// DHT Sensor setup
#define DHT_PIN 26           // Pin connected to the DHT sensor (change if necessary)
#define DHT_TYPE DHT11       // DHT11 or DHT22 (change if you're using a DHT11)

DHT dht(DHT_PIN, DHT_TYPE); // Initialize DHT sensor

WiFiClient client;
HTTPClient http;

void setup() {
  Serial.begin(115200);

  // Connect to WiFi
  WiFi.begin(ssid, password);
  Serial.println("Connecting to WiFi...");

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println();
  Serial.print("Connected to WiFi, IP Address: ");
  Serial.println(WiFi.localIP());

  // Initialize the DHT sensor
  dht.begin();

  // Initial message for clarity
  Serial.println("Timer set to 5 seconds. It will take 10 seconds before publishing the first reading.");
}

void loop() {
  // Check if it's time to send a new HTTP request
  if (millis() - lastTime >= timerDelay) {
    if (WiFi.status() == WL_CONNECTED) {
      // Read temperature and humidity from DHT sensor
      float temperature = dht.readTemperature();  // Get temperature in Celsius
      float humidity = dht.readHumidity();       // Get humidity percentage

      // Check if reading was successful
      if (isnan(temperature) || isnan(humidity)) {
        Serial.println("Failed to read from DHT sensor!");
        return;
      }
      // Construct the server path with temperature and humidity data
      String serverPath = serverName + "&field1=" + String(temperature) + "&field2=" + String(humidity);

      // Start HTTP request
      http.begin(client, serverPath.c_str());

      // Send HTTP GET request
      int httpResponseCode = http.GET();

      if (httpResponseCode > 0) {
        Serial.print("HTTP Response code: ");
        Serial.println(httpResponseCode);
        String payload = http.getString();
        Serial.println(payload);  // Print the response payload
      } else {
        Serial.print("Error code: ");
        Serial.println(httpResponseCode);  // Error code if request failed
      }
      // End the HTTP request and free resources
      http.end();
    } else {
      Serial.println("WiFi Disconnected");
    }
    // Update lastTime to manage the delay
    lastTime = millis();
  }
}
  1. Select Board โ†’ ESP32 Dev Module
  2. Select the correct COM Port
  3. Then Click Upload
  4. Open Serial Monitor (115200 baud)

If everything is correct, youโ€™ll see: Connected to WiFi, IP Address: 192.168.X.Y

๐Ÿ“Š Step 5: View Data on ThingSpeak

  • Now open your ThingSpeak channel
  • Youโ€™ll see live temperature & humidity graphs
  • Data updates every 5 seconds

๐ŸŽ‰ You can now monitor your home from anywhere in the world using just a browser or phone.

4๏ธโƒฃ How the Project Works?

๐Ÿ“š 1. Including Libraries

#include <WiFi.h>
#include <HTTPClient.h>
#include <DHT.h>
  • WiFi.h: Manages WiFi connections (authentication, IP assignment, network protocols)
  • HTTPClient.h: Handles HTTP/HTTPS communication (GET/POST requests, headers, responses)
  • DHT.h: Controls DHT sensors using one-wire protocol

๐ŸŒ 2. Set up WiFi Credentials

// Replace with your network credentials
const char* ssid = "REPLACE_WITH_YOUR_SSID";
const char* password = "REPLACE_WITH_YOUR_PASSWORD";
  • These are your WiFi network details
  • The ESP32 uses them to access the internet

โ˜๏ธ 3. Creating ThingSpeak Server URL

// Replace with your ThingSpeak API Key
String serverName = "http://api.thingspeak.com/update?api_key=REPLACE_WITH_YOUR_API_KEY";
  • This URL tells the ESP32 where to send the data
  • The API key identifies your ThingSpeak channel
  • Sensor values will be added later using field1 and field2

โฑ๏ธ 4. Timer Configuration

// Timer setup
unsigned long lastTime = 0;
const unsigned long timerDelay = 5000; // 5 seconds delay
  • We need to prevent sending data too often
  • So this ensures that data is sent every 5 seconds
  • by using millis() instead of delay() for better performance

๐ŸŒก๏ธ 5. DHT Sensor Setup

// DHT Sensor setup
#define DHT_PIN 26           // Pin connected to the DHT sensor (change if necessary)
#define DHT_TYPE DHT11       // DHT11 or DHT22 (change if you're using a DHT11)

DHT dht(DHT_PIN, DHT_TYPE); // Initialize DHT sensor Object

๐ŸŒ 6. Network & HTTP Objects

WiFiClient client;
HTTPClient http;
  • WiFiClient handles the client network connection
  • HTTPClient to send HTTP GET requests to ThingSpeak

โš™๏ธ 7. setup() Function

void setup() {
  Serial.begin(115200);

  // Connect to WiFi
  WiFi.begin(ssid, password);
  Serial.println("Connecting to WiFi...");

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println();
  Serial.print("Connected to WiFi, IP Address: ");
  Serial.println(WiFi.localIP());

  // Initialize the DHT sensor
  dht.begin();

  // Initial message for clarity
  Serial.println("Timer set to 5 seconds. It will take 10 seconds before publishing the first reading.");
}

First, we start the “Serial Monitor” to see debug messages. Then our ESP32 connects to the WiFi network and waits until the connection is successful.

Once connected, the DHT sensor is initialized, and the board is ready to start working.

ย โš™๏ธ 8. Loop() FUNCTION

Under the loop:

ย ๐ŸŒก๏ธ Our ESP32 reads the temperature and humidity values from the DHT sensor using the DHT library:

      float temperature = dht.readTemperature();  // Get temperature in Celsius
      float humidity = dht.readHumidity();       // Get humidity percentage

      // Check if reading was successful
      if (isnan(temperature) || isnan(humidity)) {
        Serial.println("Failed to read from DHT sensor!");
        return;
      }

โœ… If the readings are valid, the ESP32 creates a ThingSpeak update URL by attaching the temperature and humidity values to the API request.

String serverPath = serverName + "&field1=" + String(temperature) + "&field2=" + String(humidity);

๐Ÿ“ž An HTTP GET request is sent to ThingSpeak using this URL.

      // Start HTTP request
      http.begin(client, serverPath.c_str());

      // Send HTTP GET request
      int httpResponseCode = http.GET();

      if (httpResponseCode > 0) {
        Serial.print("HTTP Response code: ");
        Serial.println(httpResponseCode);
        String payload = http.getString();
        Serial.println(payload);  // Print the response payload
      } else {
        Serial.print("Error code: ");
        Serial.println(httpResponseCode);  // Error code if request failed
      }

ThingSpeak receives the data, stores it in the channel fields, and updates the live graphs automatically.

After sending the data, the HTTP connection is closed to free memory and ensure stable communication.

5๏ธโƒฃ ๐Ÿ Conclusion

Youโ€™ve successfully built an IoT house monitoring system using ESP32, DHT sensor, and ThingSpeak โ˜๏ธ.

This project is a solid foundation for smart homes, weather stations, and remote monitoring systems. You now have:

โœ… Real-time monitoring of your home’s climate
โœ… Historical data to track trends over time
โœ… Remote access from anywhere in the world
โœ… Customizable system you can expand as needed

๐Ÿ“Œ Resources

๐Ÿ”ฎ Project Improvements & Ideas

  • Add email alerts using ThingSpeak MATLAB
  • Display data on an LCD or OLED
  • Add multiple rooms / sensors
  • Use deep sleep for battery projects
  • Create a mobile app dashboard

Previous Post:Create an ESP32 Web Ser...
Next Post:Using an LCD Display wi...

Related Posts